Definitions

For ease of reading, this is what I mean when I use the following terms

Present Value – Discount the cash transaction to the base date in the model

Current Value – Multiply cash by factor to bring value to current time

Note: I changed the calculation in Net Cash flow GP – Estimated to account for LP distributions. The previous formula only considered the payment in the current period, and ignored it in future periods.

**[0] Net Cash Glow GP**

* This Row counts the cumulative cash on hand of the GP.
* Formula
  + =IF(T$11="","",+T47+SUM(OFFSET($S$53,0,0,1,T$11)))
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Next, [Total Distributions to LPs] are subtracted from [Cumulative cash generated by the business]

* Explanation
  + The first IF statement determines whether the row should end
  + The second term calculates the cash available to the GP. This is the cash in the business, less what has been paid to LPs.

**[1] Value of Cash Available to Investors**

* This row checks if there is cash available for investors, and provides the amount of cash that is available.
* Formula
  + {=IF(T11="","",IF($X$3=T$11,T47,IF(MIN(OFFSET(T47,0,1,1,$X$3-T$11)-OFFSET(T47,0,0,1,$X$3-T$11))<0,0,T47+SUM(OFFSET($S$53,0,0,1,S11)))))}
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Next, check if [column of table] is the [last column of table], if it is return [Cash in business]

* Next, check if [Cash flow at point *t + 1*] is greater than [Cash flow at point *t*], where *t* is from 0, 1, …, Last column of model – 1. If true, return [Cash in business] less [Total Distributions to LPs]
* Explanation
  + The first IF statement determines whether the column should end
  + The second term checks to see if cash is an increasing function of time. If it is, the business can distribute cash and still sustain operations. The cash the business has is equal to the sum of LP investments and Cash generated by the business, less what has been distributed back to LPs.

**[2] Number of Distributions to LPs**

* This row keeps a running count of the number of LPs who have had cash distributed to them including the current period.
* Formula
  + =IF(T12="","",MAX(IF(T11=$X$3,$R$5,MIN(S51+ROUNDDOWN(T50/($D$4\*(1+$U$4)^YEARFRAC($S$12,T12,$X$4)),0),$R$5)),0))
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Check if the [current column] is the last column in the table. If it is, return [Number of LPs]

* Otherwise, return[Number of Distributions in the previous period] plus [Number of Distributions in the current period]
* Explanation
  + If it is the last period in the table, all investors have to be paid. As a result, the count has to be the number of LPs.
  + It was noted that the investor column used the first cell as a base, and calculated the current value of that depending on the time period the investor entered. Using the first cell of that table as a reference, find the greatest integer number of investors that can be paid provided that the sum of payments is less than **[1]**.

**[3] Number of** Distributions to LPs - Estimated

* This row determines the value of the payments to investors.
* Formula
  + {=IF(S$11="","",IF($R$4=FALSE,0-SUM((OFFSET($E$4,0,0,$R$5,1)>OFFSET(S$12,0,-1))\*(OFFSET($E$4,0,0,$R$5,1)<=OFFSET(S$12,0,0))\*(OFFSET($F$4,0,0,$R$5,1))),$D$4\*(OFFSET(S51,0,-1)-OFFSET(S51,0,0))\*(1+$U$4)^YEARFRAC($S$12,S12,$X$4)))}
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Next, check if [Optimization Engine] is off. If it is, sum [Cash Paid to Investors] where [Date of Payout] is greater than [Previous time period], and [Date of Payout] is less than or equal to [Current time period]
3. Otherwise, take [Base payment] multiplied by [Negative number of investors paid in period] and multiplied by [Current value factor]

* Explanation
  + The first IF statement determines whether the column should end
  + The second IF statement checks if the sheet should find the optimal time to pay investors. If that is not the intention, a table of exit dates and exit payments is provided, and the cell will return a value based on that table.
  + If the intention is to find the optimal time to pay investors:
    - The total number of investors paid to date is calculated in **[2]**, the number paid in the current period is the change in the sum total. This is multiplied by the base payment factor as the spreadsheet assumes the present value of all LP investments are the same. The payment for the period is the current value of this product.

**[4] Date of distribution to LP**

* This column provides the date each LP has cash distributed to them.
* Formula
  + =IF($B4="","",IF($S$3=TRUE,OFFSET($T$12,0,$Y$3-1),IF($S$4=FALSE,OFFSET($T$12,0,$Y$3-1),IF(OFFSET(F4,-1,0)=OFFSET($T$12,0,$Y$3-1),OFFSET(F4,-1,0),OFFSET($T$12,0,COUNTIF(OFFSET($T$51,0,0,1,$Y$3),"<"&B4))))))
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Check if [Circular Reference Breaker] is TRUE, and [Optimization Engine] is FALSE. If it is, return the date of the last column in the table.
3. Otherwise. Scan **[3]** for the number of values less than the LP’s number in the list. Offset the date by this number.

* Explanation
  + If the goal of the model is not to find the optimal exit date, assume it is the last date.
  + If the goal is to find the optimal payment dates, count the number of periods where the number of LPs paid is less than the current LP’s number in the list. Use this to find the date the LP gets their cash distribution.

**[5] Amount of Distribution to LP**

* This column returns the amount distributed to each LP.
* Formula
* =IF($B4="","",IF($S$3=TRUE,0,D4\*(1+$V$4)^YEARFRAC(C4,F4,$Y$4)))
* Translation

1. If [the value of the date] is blank, then the final output is blank, otherwise continue with formula
2. Check if [Circular Reference Breaker] is TRUE, return 0.
3. Otherwise, find the value of the investment at the exit date.

* Explanation
  + The date the LP is paid is provided in **[4]**, and the date they enter is known. By the investment contract, the LP is owed a rate of [Yield] on their investment, so calculate what they are owed.
  + On a side note, I tried actually looking up the value, and using this calculation. There is a discrepancy of approximately $8k per investor, which is 0.1% per investor on average. This is not big, and the method used is more accurate by the contract, so I decided to use that.